build.gradle.kts
4.12 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
import java.util.Properties
import java.io.FileInputStream
plugins {
alias(libs.plugins.android.application)
alias(libs.plugins.kotlin.android)
alias(libs.plugins.compose.compiler)
alias(libs.plugins.ksp)
}
val keysFile = rootProject.file("keys.properties")
val keys = Properties().apply {
if (keysFile.exists()) FileInputStream(keysFile).use { load(it) }
}
fun key(name: String): String = (keys[name] as? String).orEmpty()
android {
namespace = "com.lemon.lifelog"
compileSdk = 35
defaultConfig {
applicationId = "com.lemon.lifelog"
minSdk = 30
targetSdk = 35
versionCode = 1
versionName = "0.1.0"
ndk {
// Pixel 8 Pro only — arm64-v8a. Drop other ABIs to keep APK ~35MB instead of ~140MB.
abiFilters += "arm64-v8a"
}
buildConfigField("String", "XFYUN_APPID", "\"${key("xfyun.appid")}\"")
buildConfigField("String", "XFYUN_API_KEY", "\"${key("xfyun.apiKey")}\"")
buildConfigField("String", "XFYUN_API_SECRET", "\"${key("xfyun.apiSecret")}\"")
buildConfigField("String", "XFYUN_IAT_HOST", "\"${key("xfyun.iatHost").ifEmpty { "iat.xf-yun.com" }}\"")
buildConfigField("String", "XFYUN_IAT_PATH", "\"${key("xfyun.iatPath").ifEmpty { "/v1" }}\"")
buildConfigField("String", "HERMES_API_URL", "\"${key("hermes.apiUrl").ifEmpty { "http://127.0.0.1:8642" }}\"")
buildConfigField("String", "HERMES_API_KEY", "\"${key("hermes.apiKey")}\"")
buildConfigField("String", "HERMES_MODEL", "\"${key("hermes.model").ifEmpty { "kimi-for-coding" }}\"")
}
packaging {
jniLibs {
// sherpa-onnx libs are not page-aligned for 16K page; uncompress in APK so Android 14+ can mmap.
useLegacyPackaging = false
}
}
androidResources {
// 模型保持不压缩，sherpa-onnx / TFLite 才能直接从 assets mmap。
noCompress.add("onnx")
noCompress.add("tflite")
}
buildTypes {
debug {
isMinifyEnabled = false
}
release {
isMinifyEnabled = false
proguardFiles(
getDefaultProguardFile("proguard-android-optimize.txt"),
"proguard-rules.pro"
)
}
}
compileOptions {
sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17
}
kotlinOptions {
jvmTarget = "17"
}
buildFeatures {
compose = true
buildConfig = true
}
sourceSets {
getByName("main").java.srcDirs("src/main/kotlin")
}
}
dependencies {
implementation(libs.core.ktx)
implementation(libs.lifecycle.runtime.ktx)
implementation(libs.lifecycle.viewmodel.ktx)
implementation(libs.lifecycle.viewmodel.compose)
implementation(libs.activity.compose)
implementation(platform(libs.compose.bom))
implementation(libs.compose.ui)
implementation(libs.compose.ui.graphics)
implementation(libs.compose.ui.tooling.preview)
implementation(libs.compose.material3)
debugImplementation(libs.compose.ui.tooling)
implementation(libs.room.runtime)
implementation(libs.room.ktx)
ksp(libs.room.compiler)
implementation(libs.work.runtime.ktx)
implementation(libs.okhttp)
implementation(libs.coroutines.android)
// 人脸：ML Kit 检测+5关键点（端侧，与 sherpa 的 onnxruntime 零冲突）
// + TFLite MobileFaceNet(ArcFace) embedding。不能用 onnxruntime-android——
// 它和 sherpa 自带的 libonnxruntime.so(自定义符号版本)无法共存。
implementation("com.google.mlkit:face-detection:16.1.7")
implementation("org.tensorflow:tensorflow-lite:2.16.1")
// EXIF：照片拍摄时间 + GPS。
implementation("androidx.exifinterface:exifinterface:1.3.7")
// 相册图片异步加载/缓存。
implementation("io.coil-kt:coil-compose:2.7.0")
// 端上解密微信 EnMicroMsg.db（SQLCipher，cipher_compatibility=1 读旧版加密库）→ 聊天本地化。
implementation("net.zetetic:android-database-sqlcipher:4.5.4")
implementation("androidx.sqlite:sqlite:2.4.0")
}